#READ spellrep.tt
#READ path.tt
#READ travel.tt
#READ search.tt
#READ return.tt
#READ autoassist.tt
#READ glance.tt

#VAR bag {wondrous}
#VAR bag2 {silvery}
#VAR book {tome}
#VAR myname {Elner}

#ACT {You receive your share of experience.}  {
	#IF {$docast == 1} {dco};
    #IF {$autoassist == 1} {#var assist 1};
	#IF {$tosaydie == 1} {#IF {$saydie == 0} {#var saydie 1;#untick dodie}};
	#IF {$botting == 1} {get coins corpse;p all.coin;srm};
	#var singlemob 0;
    #VAR ccph 0;
    #VAR ccawf 0
}

#SUB {You have finished memorizing %0.} { <100>++ <140>+  <070>%0 <140>+ <100>++<090>}

#ALIAS srm {rest;mem}
#ALIAS fo {fols}
#ALIAS rn {fo name %1 %2}

#MACRO {\C-e} {glan $enemy}

#NOP =========================================
#NOP  Oblivion Dagger
#NOP =========================================

#VAR saydie 0
#var tosaydie 0

#ALIAS {tdie} {
     #IF {$tosaydie == 1} {
                #VAR tosaydie 0;
				#VAR saydie 0;
                #ECHO {%c%h} {{red} { AUTO SAY DIE off }}
                } {
                #VAR tosaydie 1;
				#VAR saydie 1;
                #ECHO {%c%h} {{green} { AUTO SAY DIE on }}
                }
}

#ACT { EC: awful } {#IF {$tosaydie == 1} {#IF {$saydie == 1} {#var saydie 0;#tick dodie {say die} {3}}}}

#NOP =========================================
#NOP  Botting
#NOP =========================================

#VAR botting 0

#ALIAS dk {
	#var enemy %1;
	order moe kill $enemy;
	order moe kill $enemy;
	order larry c 'belt' $enemy;
	aa;
	aa;
	sadd cont;sadd cont;sadd cont;sadd belt;sadd belt;
	srun
}

#ACT {A dark chill from beyond the grave seems to permeate the air around} {
	#IF {$botting == 1} {
		#var pu_spectre 0;
		#tick pucountdown {$var pu_spectre 1;#untick pucountdown} {700}	
	}
}

#ACT {%0 starts to move with uncanny speed!} {
	#IF {$botting == 1} {
		#var hst_spectre 0;
		#tick hstcountdown {#var hst_spectre 1;#untick hstcountdown} {240}
	}
}

#ALIAS {tbot} {
     #IF {$botting == 1} {
                #VAR botting 0;
                #ECHO {%c%h} {{red} { BOTTING off }}
                } {
                #VAR botting 1;
                #ECHO {%c%h} {{green} { BOTTING on }}
                }
}

#ALIAS sadd {#list tocastlist ins -1 %0;#show <100>...<090> Added <130>%0 <090>to cast queue}
#ALIAS sdel {#list tocastlist fnd %0 tocastdelidx;#list tocastlist del {$tocastdelidx}}

#VAR tocast 1
#VAR spell_run 0

#ALIAS srun {
	#var spell_run 1;
	#list tocastlist len tcindex;
	#list tocastlist get $tocast nextspell;
	$nextspell
}

#NOP =========================================
#NOP  Pet Commands
#NOP =========================================

#ALIAS of {order followers %0}
#ALIAS off {order followers flee}
#ALIAS ofke {order followers kill $enemy}
#ALIAS ofbe {order followers bash $enemy}
#ALIAS rm {order followers rescue $myname}
#ALIAS ofc {order followers c %0}
#ALIAS ofce {order followers c %0 $enemy}
#ALIAS o1 {order 1.follower %0}
#ALIAS o2 {order 2.follower %0}
#ALIAS o3 {order 3.follower %0}
#ALIAS o4 {order 4.follower %0}
#ALIAS o1c {order 1.follower c %0}
#ALIAS o2c {order 2.follower c %0}
#ALIAS o3c {order 3.follower c %0}

#NOP =========================================
#NOP  Docast, repeats single spell
#NOP =========================================

#ALIAS dc {
    #var docast 1;
    #var tocast %0;
    $tocast;
}

#ACT {You don't have that spell memorized.} {
    #IF {$docast == 1} {
        #unvar tocast;
        #var docast 0;
    };
	#IF {$spell_run == 1} {
        #math tocast {$tocast + 1};
        #list tocastlist len tcindex;
        #IF {$tocast <= $tcindex} {
        #list tocastlist get $tocast nextspell;
        #delay {2} {$nextspell};
        } {#ECHO {Finished spell run.};#var spell_run 0;#list tocastlist clr;#var tocast 1}
    }
}

#ALIAS dco {#var docast 0;#unvar tocast}
#ALIAS dca {#var docast 0;abort;#unvar tocast}

#NOP =========================================
#NOP  Auto Preserver
#NOP =========================================

#VAR pres_1round {0}
#VAR pres_auto {0}

#ALIAS {apres} {
	#IF {$pres_auto == 1} {
		#showme <050>---- <150>AUTO preserving<090> %1 <050>----<090>
	} {
		#VAR pres_1round 1;
		#VAR preslength 0;
		#VAR tpreslength 0
	};
	#VAR pres_target {%1};
	mem;
	#VAR ppoint 1;
	pres %1
}

#ACT { circle) %1 - preserve} {#VAR pres_avail %1}
#ACT {Corpse of %0 is preserved for %1 additional hours.} {
	#VAR thecorpse %0;
	#MATH preslength {$preslength + %1}
}

#ALIAS rep_pres {#MATH tpreslengthh {$preslength / 60};#MATH tpreslengthm {$preslength % 60};#showme <110>---- <010>$thecorpse<110>: <090>preserved for <060>$tpreslengthh <160>hours<090> <060>$tpreslengthm <160>minutes<090>.}

#ACT {You complete your spell...} {
	#IF {$pres_auto == 1 || $pres_1round == 1} {
		#delay {2};
		#MATH ppoint {$ppoint + 1};
		#IF {$ppoint <= $pres_avail} {
			pres $pres_target
		} {#delay {4} {rep_pres;srm} }
	};
	#IF {$docast == 1} {
        $tocast;
    };
	#IF {$spell_run == 1} {
		#math tocast {$tocast + 1};
		#list tocastlist len tcindex;
		#IF {$tocast <= $tcindex} {
		#list tocastlist get $tocast nextspell;
		#delay {2} {$nextspell};
		} {#ECHO {Finished spell run.};#var spell_run 0;#list tocastlist clr;#var tocast 1}
	}

}

#ALIAS {tpres} {
        #IF {$pres_auto == 1} {
                #VAR pres_auto 0;
                #VAR tpreslength 0;
                #VAR preslength 0;
                #ECHO {%c%h} {{red} { AUTO PRESERVER off }}
        } {
				#VAR preslength 0;
                #VAR pres_auto 1;
                #ECHO {%c%h} {{green} { AUTO PRESERVER on }}
        }
}

#ACT {Your studies are complete.} {
	st;
	#IF {$pres_auto == 1} {
        #delay {2} {apres $pres_target}
    } { #VAR preslength 0;#VAR tpreslength 0 };
    #IF {$pres_1round == 1} {
        #VAR pres_1round 0;
    };
	#IF {$botting == 1} {
		#VAR tocast 1;
		#IF {$hst_spectre == 1} {sadd hst spectre};
		#IF {$pu_spectre == 1} {sadd pu spectre};
		srun;
		#if {$bugbears == 1 || $duergars == 1} {#var walkable 1;#delay {25} l}
	}
}

#ACT {You abort your spell} {
	#IF {$spell_run == 1} {
		#math tocast {$tocast + 1}
		#list tocastlist len tcindex;
		#IF {$tocast <= $tcindex} {
        #list tocastlist get $tocast nextspell;
        #delay {2} {$nextspell};
        } {
		#ECHO {Finished spell run.};
		#var spell_run 0;#list tocastlist clr;#var tocast 1;
		}
	};	
	#ECHO {%c%h} {{red} { SPELL ABORTED }}
}

#NOP =========================================
#NOP  Spell Aliases
#NOP =========================================

#ALIAS ashadow {c 'animate shad' %1}
#ALIAS awight {c 'animate wight' %1}
#ALIAS aghast {c 'animate ghast' %1}
#ALIAS awraith {c 'animate wraith' %1}
#ALIAS aspectre {c 'animate spectre' %1}
#ALIAS aghost {c 'animate ghost' %1}

#ALIAS pres {c 'preserv' %1}
#ALIAS dm {c 'detect mag' %1}
#ALIAS di {c 'detect invis' %1}
#ALIAS invis {c 'invis' %1}
#ALIAS mf {c 'mage flame' %1}
#ALIAS mm {c 'magic missile' %1}
#ALIAS chill {c 'chill touch' %1}
#ALIAS mc {c 'minor creat' %1}
#ALIAS command {c 'command undead' %1}
#ALIAS pfu {c 'prot from undead' %1}
#ALIAS sb {c 'soul bind' %1}
#ALIAS sleep {c 'sleep' %1}
#ALIAS spect {c 'spectral hand' %1}
#ALIAS dispel {c 'dispel magi' %1}
#ALIAS with {c 'wither' %1}
#ALIAS tele {c 'teleport' %1}
#ALIAS edrain {c 'energy drain' %1}
#ALIAS ray {c 'ray of enfeeb' %1}
#ALIAS lev {c 'levi' %1}
#ALIAS feeb {c 'feeble' %1}
#ALIAS csh {c 'coldshield'}
#ALIAS h {c 'heal undead' %1}
#ALIAS teeth {c 'snapp teeth' %1}
#ALIAS hst {c 'haste' %1}
#ALIAS cone {c 'cone of cold' %1}
#ALIAS nerve {c 'nerve dance' %1}
#ALIAS globe {c 'globe of invul' %1}
#ALIAS rejuv {c 'rejuv major' %1}
#ALIAS dd {c 'dimension door' %1}
#ALIAS belt {c 'beltyns' %1}
#ALIAS pu {c 'prot undead' %1}
#ALIAS glam {c 'corpse glam' %1}
#ALIAS shackle {c 'soul shackl'}
#ALIAS mantle {c 'blackmant' %1}
#ALIAS cont {c 'contagion' %1}
#ALIAS abi {c 'abi dalz' %1}
#ALIAS erad {c 'eradicate undead' %1}
#ALIAS wail {c 'banshee wail'}
#ALIAS bone {c 'boneshatt' %1}
#ALIAS rain {c 'rain of blood' %1}
#ALIAS siphon {c 'siphon undead'}
#ALIAS embalm {c 'embalm' %1}
#ALIAS loc {c 'locate remains'}
#ALIAS drain {c 'life drain' %1}
#ALIAS touch {c 'lich touch' %1}
#ALIAS rot {c 'living rot'}
#ALIAS tomb {c 'ice tomb' %1}
#ALIAS pact {c 'death pact'}
#ALIAS pt {c 'pain touch' %1}

#SHOWME __ LICH.tt