#READ spellrep.tt
#READ path.tt
#READ travel.tt
#READ search.tt
#READ return.tt
#READ autoassist.tt
#READ glance.tt

#VAR bag {wondrous}
#VAR bag2 {silvery}
#VAR pbag {doors}
#VAR myname {Nil}

#ACT {You receive your share of experience.}  {
    #if {$autoassist == 1} {#var assist 1};
	#IF {$docast == 1} {dco};
    #VAR checkcast 0;
    #VAR ccph 0;
    #VAR ccawf 0
}

#SUB {You have finished praying for %0.} { <100>[[ <050>_<150>_ <070>%0 <150>_<050>_<100> ]]<090>}
#ALIAS srp {rest;pray}

#ACT {%0 suddenly looks worried.} {gsay Ther be a hex on %0}
#ACT {%0 suddenly looks speechless!} {gsay %0 been silenced.}

#NOP ALIAS myvits {}

#NOP =========================================
#NOP  Vit Highlighter
#NOP =========================================

#ALIAS vadd {
	#tab @upfirst{%1};#list vitlist ins 1 @upfirst{%1};
	#show <100>...<090> Added <140>@upfirst{%1}<090> to the Vit list.
}

#ALIAS vlist {
	#list vitlist len vlindex;
	#IF {$vlindex == 0} {#echo {%c%p} {{red} {== NO VIT LIST ========}}} {
		#echo {%c%p} {{blue} {== Vit LIST ============}};
		#showme;
		#loop {1 $vlindex} {#echo {<140>..V <090>- $vitlist[&0]}};
		#loop {1 $vlindex} {
        #SUB {%%1/%%2 move %%3/%%4 hit - $vitlist[&0]} {<090>%%1/%%2 move %%3/%%4 <120>hit <100>- <140>$vitlist[&0]<090>}}
	};
	#echo {%c%p} {{light black} {---------------------------}};
}

#ALIAS vclear {
	#UNSUB {%1*};
	#list vitlist clr;#var vlindex 0;#show Vit List CLEARED
}

#NOP =========================================
#NOP  Docast, repeats single spell
#NOP =========================================

#ALIAS dc {
    #var docast 1;
    #var tocast %0;
    $tocast;
}

#ALIAS dco {#var docast 0;#unvar tocast}
#ALIAS dca {#var docast 0;abort;#unvar tocast}

#NOP =========================================
#NOP  Spirit Elk 
#NOP =========================================

#ALIAS totem {g totem;hold totem;use totem;#delay {2} {order followers rep};rem totem;p totem}

#ALIAS rm {order elk resc $myname}
#ALIAS off {order elk flee}
#ALIAS ofke {order elk kill $enemy}
#ALIAS r {order elk resc %1}
#ALIAS of {order elk %0}

#NOP =========================================
#NOP  Auto Preserver
#NOP =========================================

#VAR pres_1round {0}
#VAR pres_auto {0}

#ALIAS {apres} {
	#IF {$pres_auto == 1} {
		#showme <050>---- <150>AUTO preserving<090> %1 <050>----<090>
	} {
		#VAR pres_1round 1;
		#VAR preslength 0;
		#VAR tpreslength 0
	};
	#VAR pres_target {%1};
	pray;
	#VAR ppoint 1;
	pres %1
}

#ACT {%1 - preserve} {#VAR pres_avail %1}
#ACT {Corpse of %0 is preserved for %1 additional hours.} {
	#VAR thecorpse %0;
	#MATH preslength {$preslength + %1}
}

#ALIAS rep_pres {#MATH tpreslengthh {$preslength / 60};#MATH tpreslengthm {$preslength % 60};#showme <110>---- <010>$thecorpse<110>: <090>preserved for <060>$tpreslengthh <160>hours<090> <060>$tpreslengthm <160>minutes<090>.}
#ALIAS say_pres {#MATH tpreslengthh {$preslength / 60};#MATH tpreslengthm {$preslength % 60};say I preserved $thecorpse fer $tpreslengthh hours and $tpreslengthm minutes.}

#ACT {You don't have that spell memorized.} {
    #IF {$docast == 1} {
        #unvar tocast;
        #var docast 0;
    }
}

#ACT {You complete your spell...} {
	#IF {$docast == 1} {
        $tocast;
    };
	#IF {$expmode == 1} {
        #var icasted {$icasted + 1}
    }; 
	#IF {$pres_auto == 1 || $pres_1round == 1} {
		#delay {2};
		#MATH ppoint {$ppoint + 1};
		#IF {$ppoint <= $pres_avail} {
			pres $pres_target
		} {#delay {4} {say_pres;srp} }
	}
}

#ALIAS {tpres} {
        #IF {$pres_auto == 1} {
                #VAR pres_auto 0;
                #VAR tpreslength 0;
                #VAR preslength 0;
                #ECHO {%c%h} {{red} { AUTO PRESERVER off }}
        } {
				#VAR preslength 0;
                #VAR pres_auto 1;
                #ECHO {%c%h} {{green} { AUTO PRESERVER on }}
        }
}

#ACT {Your prayers are complete.} {
	st;
	#IF {$pres_auto == 1} {
        #delay {2} {apres $pres_target}
    } { #VAR preslength 0;#VAR tpreslength 0 };
    #IF {$pres_1round == 1} {
        #VAR pres_1round 0;
    };
	#IF {$expmode == 1} {
        pray;st;ret;aa;#VAR checkcast 0;#VAR icasted 0;#VAR inmem 0;#var amhealing 0;
        #IF {$stonewhenback == 1} {sst};
    }
}

#NOP =========================================
#NOP  Auto Stone
#NOP =========================================

#ACT {You can't do this sitting!} {st}
#ACT {You stumble, but manage to avoid falling!} {
    #IF {$stonewhenback == 1} {
        #IF {$incombat != 1} {#DELAY {12} {aa}}
    } {#IF {$incombat != 1} {aa}}
}
#ACT {You can't concentrate with all the racket!} {#IF {$expmode == 1} {st;ret;aa;#VAR inmem 0}}

#ACT { EC: awful } {#IF {$expmode == 1} {#VAR checkcast 1}}

#ACT {$tank group-says '$ssot'} {
    #VAR stonetank 1;
    #IF {$expmode == 1} {
        #IF {$inmem == 1 || $checkcast == 1 || $incombat == 0} {#VAR stonewhenback 1} {
        sst
        }; 
    }
} {4}

#ACT {You abort your prayer} {
	#IF {$autocast == 1} {
		#VAR icasted {$icasted + 1}
	};
	#VAR amhealing 0;
	#ECHO {%c%h} {{red} { SPELL ABORTED }}
}

#ACT {$tank's skin seems to turn to stone.} {
    #IF {$expmode == 1} {
        #VAR stonewhenback 0;
        #VAR stonetank 0;
    }
}

#ACT {You're busy spellcasting!} {
    #IF {$expmode == 1} {
	    #IF {$stonetank == 1} {#VAR amhealing 0;#VAR stonewhenback 1};
    }
} {3}

#ALIAS {sst} {#IF {$checkcast == 1} {#VAR stonewhenback 1} {ss $tank}}
#ALIAS {sso} {#VAR {ssot} {%0}}

#ALIAS {texp} {
     #IF {$expmode == 1} {
                #VAR expmode 0;
                #ECHO {%c%h} {{red} { EXPING MODE off }}
                } {
                #VAR expmode 1;
                #ECHO {%c%h} {{green} { EXPING MODE on }}
                }
}

#NOP =========================================
#NOP  Auto Healer
#NOP =========================================

#VAR amhealing 0
#VAR doheal 0

#ALIAS {ht} {#IF {$checkcast == 1} {#VAR amhealing 0} {#VAR doheal ht;h $tank}}
#ALIAS {dgh} {#IF {$checkcast == 1} {#VAR amhealing 0} {#VAR doheal gh;gh}}

#ACT {< T: $tank TC: [small wounds|few wounds|nasty wounds]} {
	#IF {$expmode == 1 && $amhealing == 0 && $stonetank == 0} {
		#VAR amhealing 1;
		pray;
		#delay {3} {
		#IF {$hleft != 0} 
			{#MATH hleft {$hleft - 1};ht} 
			{dgh}
	}}
}

#ACT {You summon a holy light to surround $tank, closing some of [his|her|its] wounds.} {
	#IF {$expmode == 1} {
		#VAR amhealing 0;
	}
}

#ACT {You summon a holy light that surrounds the entire group.} {
	#IF {$expmode == 1} {
		#VAR amhealing 0;
	}
}

#ACT {( 6th circle)  %1 - heal} {#VAR hleft %1}

#NOP =========================================
#NOP  Spell Aliases
#NOP =========================================

#ALIAS pres {c 'preserv' %1}
#ALIAS dm {c 'detect mag' %1}
#ALIAS invis {c 'invis' %1}
#ALIAS cc {c 'cure crit' %1}
#ALIAS vig {c 'vigor crit' %1}
#ALIAS cs {c 'cure serious' %1}
#ALIAS blind {c 'blind' %1}
#ALIAS h {c 'heal' %1}
#ALIAS vit {c 'vit' %1}
#ALIAS sil {c 'silen per' %1}
#ALIAS sum {tell %1 summoning you;c 'summon' %1}
#ALIAS quake {c 'earthquak'}
#ALIAS fs {c 'flame strike' %1}
#ALIAS ss {c 'stone' %1}
#ALIAS pup {c 'puppet' %1}
#ALIAS wrak {c 'spir wrack' %1}
#ALIAS wb {c 'water brea' %1}
#ALIAS gh {c 'group heal'}
#ALIAS di {c 'detect invis' %1}
#ALIAS dart {c 'totem dar' %1}
#ALIAS word {c 'word'}
#ALIAS fury {gsay +++ ancestral fury !;c 'ances fury'}
#ALIAS slow {c 'slowness' %1}
#ALIAS rp {c 'remov poi' %1}
#ALIAS hex {c 'hex' %1}
#ALIAS arm {c 'armor' %1}

#ALIAS sss {ss $myname}
#ALIAS vitm {c 'vitality' me}

#SHOWME __ SHAMAN.tt