#NOP =========================================
#NOP  Global Variables
#NOP =========================================

#VAR expmode 0
#VAR autocast 0
#VAR imafk 0
#VAR Adrag 0
#VAR Acircl 0
#VAR stonetank 0
#VAR blurtank 0
#VAR expmode 0
#VAR docast 0
#VAR checkcast 0
#VAR icasted 0
#VAR healwhenback 0
#VAR blurwhenback 0
#VAR stonewhenback 0
#VAR icasted 0
#VAR assist 0
#VAR autoassist 0
#VAR aflee 1
#VAR Agroup 0
#VAR gleader 0
#VAR myname 0
#VAR auto_path 0

#GAG {Your spell is partially absorbed}
#GAG {If you do not get a response, it's because the staff are busy or unavailable.}
#GAG {If this is a pressing matter, please mudmail admin by typing mwrite admin}
#GAG {<subject> and your message.}

#NOP =========================================
#NOP  Global Actions
#NOP =========================================

#ACT {(Head) %0 - %1} {#var gleader %1}
#ACT {< P: %1 >} {#var incombat 0}
#ACT {< T: %1 TC:} {#var incombat 1}
#ACT {Autosaving} {l;#IF {$imafk == 1} {tog afk}}
#ACT {PANIC!  You couldn't escape!}  {#IF {$aflee == 1} {flee}}
#ACT {The %1 seems to be closed.}  {#IF {$auto_path == 1} {#map undo}}
#ACT {Do you wish to create a new character?} {#IF {"$myname" != "0"} {n}}
#ACT {By what name do you wish to be known?} {#IF {"$myname" != "0"} {$myname}}

#ACT {^an ENORMOUS ice bear is dead!} {
	#var thetime {@gettime{}};
	#LOGLINE other.txt {<100>$thetime <170>an ENORMOUS icebear<070> is DEAD.<090>}
}

#ACT {You stagger, and fall to your knees!} {stand}
#ACT {%0 does an acrobatic maneuver in battle, tripping you.} {st}
#ACT {You are knocked down} {stand}
#ACT {sends you sprawling.}  {#IF {$docast} {stand;$tocast} {stand}}

#NOP =========================================
#NOP  Speedwalker
#NOP =========================================

#alias {.%0}
{
    #list cnt clr;

    #parse {%0}
    {
        #if {"&0" >= "0" && "&0" <= "9"}
        {
            #var cnt ${cnt}&0
        }
        #if {"$cnt" == ""}
        {
            #send &0
        }
        {
            #loop {1 $cnt}
            {             
                #send &0;
            };           
            #list cnt clr
        }
    }   
}

#NOP =========================================
#NOP  Couple Toggles
#NOP =========================================

#ALIAS tflee {
    #IF {$aflee == 1} {
                #VAR aflee 0;
                #ECHO {%c%h} {{red} { AUTO FLEE off }}
                } {
                #VAR aflee 1;
                #ECHO {%c%h} {{green} { AUTO FLEE on }}
        }
}

#ALIAS tafk {
    #IF {$imafk == 1} {
                #VAR imafk 0;
                #ECHO {%c%h} {{red} { AFK off }};
		#run {wasafk} {cat afkcomms.txt};
		#system {rm afkcomms.txt}
                } {
                #VAR imafk 1;
                #ECHO {%c%h} {{green} { AFK on }};
		#LOGLINE afkcomms.txt {<100>...<090>}
        }
}

#ALIAS tgroup {
        #IF {$Agroup == 1} {
                #VAR Agroup 0;
                #echo {%c%h} {{red} { AUTO GROUP off }}
                } {
                #VAR Agroup 1;
                #echo {%c%h} {{green} { AUTO GROUP on }}
                }
}

#ACT {%0 has just given you %1 consent.} {#IF {$Agroup == 1} {group %0;gsay welcome %0!}}

#NOP =========================================
#NOP  Character Loading
#NOP =========================================

#ALIAS {lrogue} {#READ rogue.tt}
#ALIAS {lsham} {#READ shaman.tt}
#ALIAS {lelem} {#READ elementalist.tt}
#ALIAS {lench} {#READ enchanter.tt}
#ALIAS {lwarr} {#READ warrior.tt}
#ALIAS {llich} {#READ lich.tt}

#ALIAS connect {#session toril torilmud.org 9999}

#NOP =========================================
#NOP  Global Macros
#NOP =========================================

#MACRO {\e[24~} {#session toril torilmud.org 9999} {^[24~}
#MACRO {\C-a} {#buffer lock}
#MACRO {\C-f} {flee}
#MACRO {\C-l} {get all corpse}
#MACRO {\eOp} {scan}
#MACRO {\eOr} {#IF {$Adrag == 1} {ds} {s}}
#MACRO {\eOs} {#IF {$Adrag == 1} {dd} {d}}
#MACRO {\eOt} {#IF {$Adrag == 1} {dw} {w}}
#MACRO {\eOu} {look room}
#MACRO {\eOv} {#IF {$Adrag == 1} {de} {e}}
#MACRO {\eOx} {#IF {$Adrag == 1} {dn} {n}}
#MACRO {\eOy} {#IF {$Adrag == 1} {du} {u}}

#NOP =========================================
#NOP  Global Aliases
#NOP =========================================

#ALIAS {'} {gsay %0}
#ALIAS {`} {#var enemy %1;con $enemy}
#ALIAS {aa} {assist $tank}
#ALIAS {f} {forget %0}
#ALIAS {pri} {prioritize %0}
#ALIAS {pp} {put %1 $pbag}
#ALIAS {p} {put %1 $bag}
#ALIAS {p2} {put %1 $bag2}
#ALIAS {gp} {get %1 $pbag}
#ALIAS {g} {get %1 $bag}
#ALIAS {g2} {get %1 $bag2}
#ALIAS {ggs} {#grep group-says}
#ALIAS {ggcc} {#grep GCC:}
#ALIAS {gpet} {#grep petition}
#ALIAS {gt} {#grep tells you}
#ALIAS {ke} {#var enemy %1;kill $enemy}
#ALIAS {lib} {look in $bag}
#ALIAS {lib2} {look in $bag2}
#ALIAS {lipb} {look in $pbag}
#ALIAS {tank} {#var tank @upfirst{%1};#echo {%c%h} {{blue} { TANK is $tank }}}
#ALIAS {w1} {#var w1 %1}
#ALIAS {w2} {#var w2 %1}
#ALIAS {wes} {who evil sort}
#ALIAS {wgs} {who good sort}
#ALIAS {wig} {who ingroup s}
#ALIAS {wns} {who neutral sort}

#ALIAS {afk} {
	#VAR wentafk {@gettime{}};
	#IF {$imafk} {#var afkmessage {%0 - Away since $wentafk EST}} {#var afkmessage {%0 - Away since $wentafk EST};tafk;tog afk}
}
#ALIAS {back} {tafk;tog afk}

#ALIAS {lic} {#IF {"%1" == ""} {#var licl 1} {#var licl %1};#loop {1 $licl} {exa &0.corpse}}
#ALIAS {lip} {#IF {"%1" == ""} {#var lipl 1} {#var lipl %1};#loop {1 $lipl} {l in &0.portal}}
#ALIAS {lipc} {#IF {"%1" == ""} {#var lipcl 1} {#var lipcl %1};#loop {1 $lipcl} {exa &0.pcorpse}}
#ALIAS {loot} {#loop {1 %1} {get all &0.corpse}}

#ALIAS po {
	#IF {"%1" == "w"} {emote points to the room to the west.};
	#IF {"%1" == "e"} {emote points to the room to the east.};
	#IF {"%1" == "s"} {emote points to the room to the south.};
	#IF {"%1" == "n"} {emote points to the room to the north.};
    #IF {"%1" == "u"} {emote points to the room above.};
    #IF {"%1" == "d"} {emote points to the room below.};
}

#NOP =========================================
#NOP  Global Functions
#NOP =========================================

#FUNCTION 		{gettime} {#FORMAT {time} {%T};#FORMAT {test} {%t} {$time};#VAR result {$test}}
#FUNCTION 		{lowercase} {#FORMAT {result} {%l} {{%0}}}
#FUNCTION		{upfirst}	{#format {result} {%n} {{%0}}}

#NOP =========================================
#NOP  Config Options
#NOP =========================================

#CONFIG           {SPEEDWALK}             {OFF}
#CONFIG           {VERBATIM}              {OFF}
#CONFIG           {REPEAT ENTER}          {OFF}
#CONFIG           {ECHO COMMAND}          {ON}
#CONFIG           {VERBOSE}               {OFF}
#CONFIG           {WORDWRAP}              {OFF}
#CONFIG           {LOG}                   {RAW}
#CONFIG           {BUFFER SIZE}           {7000}
#CONFIG           {SCROLL LOCK}           {ON}
#CONFIG           {HISTORY SIZE}          {2500}
#CONFIG           {CONNECT RETRY}         {60}
#CONFIG           {PACKET PATCH}          {0}
#CONFIG           {TINTIN CHAR}           {#}
#CONFIG           {VERBATIM CHAR}         {\}
#CONFIG           {REPEAT CHAR}           {!}
#PATHDIR          {n}                     {s}                          {1}
#PATHDIR          {e}                     {w}                          {2}
#PATHDIR          {ne}                    {sw}                         {3}
#PATHDIR          {s}                     {n}                          {4}
#PATHDIR          {se}                    {nw}                         {6}
#PATHDIR          {w}                     {e}                          {8}
#PATHDIR          {nw}                    {se}                         {9}
#PATHDIR          {sw}                    {ne}                         {12}
#PATHDIR          {u}                     {d}                          {16}
#PATHDIR          {d}                     {u}                          {32}

#NOP =========================================
#NOP  Global Subs
#NOP =========================================

#SUBSTITUTE       {^You %0five hits%1}    {<098>You %0<138>five hits<098>%1}  {5}
#SUBSTITUTE       {^You %0four hits%1}    {<098>You %0<118>four hits<098>%1}  {5}
#SUBSTITUTE       {^You %0single hit%1}   {<098>You %0<108>single hit<098>%1}  {5}
#SUBSTITUTE       {^You %0six hits%1}     {<098>You %0<128>six hits<098>%1}  {5}
#SUBSTITUTE       {^You %0three hits%1}   {<098>You %0<018>three hits<098>%1}  {5}
#SUBSTITUTE       {^You %0two hits%1}     {<098>You %0<038>two hits<098>%1}  {5}
#SUBSTITUTE       {^You %0seven hits%1}     {<098>You %0<158>seven hits<098>%1}  {5}
#SUBSTITUTE       {^You %0eight hits%1}     {<098>You %0<188>eight hits<098>%1}  {5}

#NOP =========================================
#NOP  Communication Logging
#NOP =========================================

#ACT {%1 group-says %2} {
	#IF {"$myname" == "Hibboble"} {
		#IF {"@lowercase{%2}" == "*haste*"} {
                	#var thetime {@gettime{}};
                	#LOGLINE comms.txt {<100>$thetime <090>%1 : <130>%2<090>}
        } {#tab %1;#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <090>%1 : <030>%2<090>} }
	} {
		#tab %1;#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <090>%1 : <030>%2<090>}
	}
}

#ACT {You group-say %1} {#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <120>-\> <090>: <030>%1<090>}}

#ACT {%1 tells you %2} {
	#IF {$imafk == 0} {
		#IF {"%1" == "Kegor"} {
			#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime KEGOR <090>: <060>%2<090>}
		} {
			#IF {"%1" != "* *"} {
			#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <090>%1 <100>: <170>%2<090>}}
		}
	} {
		repl $afkmessage;
		#var thetime {@gettime{}};#LOGLINE afkcomms.txt {<100>$thetime <090>%1 <100>: <170>%2<090>}
	}
}

#ACT {You tell %1 %2} {
	#IF {$imafk == 0} {
		#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <170>-\> <060>%1 <090>: <160>%2<090>}
	}
}

#ACT {%1 says %2} {#IF {"%1" != "* *"}
	{#var thetime {@gettime{}};#LOGLINE chat.txt {<100>$thetime <090>%1 : %2}}} 

#ACT {%1 responds to your petition with %2} {#IF {"%1" != "* *"}
	{#var thetime {@gettime{}};#LOGLINE comms.txt {<100>$thetime <090>%1 : <010>%2<090>}}}

#ACT {%1 GCC: %2} {#IF {"%1" != "* *"}
	{#var thetime {@gettime{}};#LOGLINE chat.txt {<100>$thetime <090>%1 : <060>%2<090>}}}

#ACT {*You have learned something new about %0!} {
	#var thetime {@gettime{}};
	#LOGLINE other.txt {<100>$thetime <020>LEARNED<090> : <120>%0<090>}
}

#ACT {You have learned something new about %0!} {
    #var thetime {@gettime{}};
    #LOGLINE other.txt {<100>$thetime <020>LEARNED<090> : <120>%0<090>}
}

#ACT {%1 OOC: %2} {#IF {"%1" != "* *"}
{#var thetime {@gettime{}};#LOGLINE chat.txt {<100>$thetime <090>%1 : <120>%2<090>}
}}

#ACT {%1 ASSOC:: %2} {#IF {"%1" != "* *"}
{#var thetime {@gettime{}};#LOGLINE chat.txt {<100>$thetime <090>%1 : <050>%2<090>}
}}

#ACT {You ASSOC: %2} {
#var thetime {@gettime{}};#LOGLINE chat.txt {<100>$thetime <090>You : <050>%2<090>}
}